Start and end: BR1 (Part 1 of 2)

       Name: BR1 (Part 1 of 2)                                       [Show more]
       Type: Subroutine
   Category: Start and end
    Summary: Show the "Load New Commander (Y/N)?" screen and start the game
    Context: See this subroutine in context in the source code
 Variations: See code variations for this subroutine in the different versions
 References: This subroutine is called as follows:
             * S% calls BR1


 BRKV is set to point to BR1 by the loading process.


.BR1

 LDX #3                 \ Set XC = 3 (set text cursor to column 3)
 STX XC

 JSR FX200              \ Disable the ESCAPE key and clear memory if the BREAK
                        \ key is pressed (*FX 200,3)

 LDX #CYL               \ Call TITLE to show a rotating Cobra Mk III (#CYL) and
 LDA #128               \ token 128 ("  LOAD NEW COMMANDER (Y/N)?{crlf}{crlf}"),
 JSR TITLE              \ returning with the internal number of the key pressed
                        \ in A

 CMP #&44               \ Did we press "Y"? If not, jump to QU5, otherwise
 BNE QU5                \ continue on to load a new commander

\.BR1                   \ These instructions are commented out in the original
\
\LDX #3                 \ source. This block starts with the same *FX call as
\STX XC                 \ above, then clears the screen, calls a routine to
\                       \ flush the keyboard buffer (FLKB) that isn't present
\JSR FX200              \ in the cassette version but is in other versions,
\                       \ and then it displays "LOAD NEW COMMANDER (Y/N)?" and
\LDA #1                 \ lists the current cargo, before falling straight into
\JSR TT66               \ the load routine below, whether or not we have
\                       \ pressed "Y". This may be a bit of testing code, as the
\JSR FLKB               \ first line is a commented label, BR1, which is where
\                       \ BRKV points, so when this is uncommented, any BRK
\LDA #14                \ instructions will jump straight to the load screen
\JSR TT214
\
\BCC QU5

 JSR GTNME              \ We want to load a new commander, so we need to get
                        \ the commander name to load

 JSR LOD                \ We then call the LOD subroutine to load the commander
                        \ file to address NA%+8, which is where we store the
                        \ commander save file

 JSR TRNME              \ Once loaded, we copy the commander name to NA%

 JSR TTX66              \ And we clear the top part of the screen and draw a
                        \ border box