Skip to navigation

⌂ ∞ ▽ Elite on the BBC Micro and NES

Drawing pixels: PIX

[BBC Micro disc version, Loader 3]

       Name: PIX                                                     [Show more]
       Type: Subroutine
   Category: Drawing pixels
    Summary: Draw a single pixel at a specific coordinate

    Context: See this subroutine in context in the source code
 References: This subroutine is called as follows:
             * PLL1 (Part 1 of 3) calls PIX
             * PLL1 (Part 2 of 3) calls PIX
             * PLL1 (Part 3 of 3) calls PIX
             * PROT2 calls via out




 Draw a pixel at screen coordinate (X, -A). The sign bit of A gets flipped
 before drawing, and then the routine uses the same approach as the PIXEL
 routine in the main game code, except it plots a single pixel from TWOS
 instead of a two pixel dash from TWOS2. This applies to the top part of the
 screen (the monochrome mode 4 space view).

 See the PIXEL routine in the main game code for more details.



 Arguments:

   X                    The screen x-coordinate of the pixel to draw

   A                    The screen y-coordinate of the pixel to draw, negated



 Other entry points:

   out                  Contains an RTS



.PIX

 TAY                    \ Copy A into Y, for use later

 EOR #%10000000         \ Flip the sign of A

 LSR A                  \ Set A = A >> 3
 LSR A
 LSR A

 LSR CHKSM+1            \ Rotate the high byte of CHKSM+1 to the right, as part
                        \ of the copy protection

 ORA #&60               \ Set ZP+1 = &60 + A >> 3
 STA ZP+1

 TXA                    \ Set ZP = (X >> 3) * 8
 EOR #%10000000
 AND #%11111000
 STA ZP

 TYA                    \ Set Y = Y mod 8, which is the pixel row within the
 AND #7                 \ character block at which we want to draw the start of
 TAY                    \ our line (as each character block has 8 rows)

 TXA                    \ Set X = X mod 8, which is the horizontal pixel number
 AND #7                 \ within the character block where the line starts (as
 TAX                    \ each pixel line in the character block is 8 pixels
                        \ wide)

 LDA TWOS,X             \ Fetch a pixel from TWOS and poke it into ZP+Y
 STA (ZP),Y

.out

 RTS                    \ Return from the subroutine