Keyboard: TT217

       Name: TT217                                                   [Show more]
       Type: Subroutine
   Category: Keyboard
    Summary: Scan the keyboard until a key is pressed
    Context: See this subroutine in context in the source code
 References: This subroutine is called as follows:
             * gnum calls TT217
             * MT26 calls TT217
             * qv calls TT217
             * TT214 calls TT217
             * mes9 calls via out
             * OUCH calls via out
             * diskerror calls via t
             * LOD calls via t
             * SVE calls via t
             * YESNO calls via t


 Scan the keyboard until a key is pressed, and return the key's ASCII code.
 If, on entry, a key is already being held down, then wait until that key is
 released first (so this routine detects the first key down event following
 the subroutine call).


 Returns:

   X                    The ASCII code of the key that was pressed

   A                    Contains the same as X

   Y                    Y is preserved


 Other entry points:

   out                  Contains an RTS

   t                    As TT217 but don't preserve Y, set it to YSAV instead


.TT217

 STY YSAV               ; Store Y in temporary storage, so we can restore it
                        ; later

.t

 LDY #2                 ; Wait for 2 delay loops to implement a simple keyboard
 JSR DELAY              ; debounce and prevent multiple key presses being
                        ; recorded

 JSR RDKEY              ; Scan the keyboard for a key press and return the
                        ; ASCII code of the key pressed in A and X (or 0 for no
                        ; key press)

 BNE t                  ; If a key was already being held down when we entered
                        ; this routine, keep looping back up to t, until the
                        ; key is released

.t2

 JSR RDKEY              ; Any pre-existing key press is now gone, so we can
                        ; start scanning the keyboard again, returning the
                        ; ASCII code of the key pressed in X (or 0 for no key
                        ; press)

 BEQ t2                 ; Keep looping up to t2 until a key is pressed

 LDY YSAV               ; Restore the original value of Y we stored above

 TAX                    ; Copy A into X

.out

 RTS                    ; Return from the subroutine