Main loop: Main flight loop (Part 4 of 16)

       Name: Main flight loop (Part 4 of 16)                         [Show more]
       Type: Subroutine
   Category: Main loop
    Summary: For each nearby ship: Copy the ship's data block from K% to the
             zero-page workspace at INWK
  Deep dive: Program flow of the main game loop
             Ship data blocks
    Context: See this subroutine in context in the source code
 References: This subroutine is called as follows:
             * KS1 calls via MAL1
             * Main flight loop (Part 12 of 16) calls via MAL1


 The main flight loop covers most of the flight-specific aspects of Elite. This
 section covers the following:

   * Start looping through all the ships in the local bubble, and for each
     one:

     * Copy the ship's data block from K% to INWK

     * Set XX0 to point to the ship's blueprint (if this is a ship)


 Other entry points:

   MAL1                 Marks the beginning of the ship analysis loop, so we
                        can jump back here from part 12 of the main flight loop
                        to work our way through each ship in the local bubble.
                        We also jump back here when a ship is removed from the
                        bubble, so we can continue processing from the next ship


.MA3

 LDX #0                 ; We're about to work our way through all the ships in
                        ; our local bubble of universe, so set a counter in X,
                        ; starting from 0, to refer to each ship slot in turn

.MAL1

 STX XSAV               ; Store the current slot number in XSAV

 LDA FRIN,X             ; Fetch the contents of this slot into A. If it is 0
 BNE P%+5               ; then this slot is empty and we have no more ships to
 JMP MA18               ; process, so jump to MA18 below, otherwise A contains
                        ; the type of ship that's in this slot, so skip over the
                        ; JMP MA18 instruction and keep going

 STA TYPE               ; Store the ship type in TYPE

 JSR GINF               ; Call GINF to fetch the address of the ship data block
                        ; for the ship in slot X and store it in INF. The data
                        ; block is in the K% workspace, which is where all the
                        ; ship data blocks are stored

                        ; Next we want to copy the ship data block from INF to
                        ; the zero-page workspace at INWK, so we can process it
                        ; more efficiently

 LDY #NI%-1             ; There are NI% bytes in each ship data block (and in
                        ; the INWK workspace, so we set a counter in Y so we can
                        ; loop through them

.MAL2

 LDA (INF),Y            ; Load the Y-th byte of INF and store it in the Y-th
 STA INWK,Y             ; byte of INWK

 DEY                    ; Decrement the loop counter

 BPL MAL2               ; Loop back for the next byte until we have copied the
                        ; last byte from INF to INWK

 LDA TYPE               ; If the ship type is negative then this indicates a
 BMI MA21               ; planet or sun, so jump down to MA21, as the next bit
                        ; sets up a pointer to the ship blueprint, and then
                        ; checks for energy bomb damage, and neither of these
                        ; apply to planets and suns

 ASL A                  ; Set Y = ship type * 2
 TAY

 LDA XX21-2,Y           ; The ship blueprints at XX21 start with a lookup
 STA XX0                ; table that points to the individual ship blueprints,
                        ; so this fetches the low byte of this particular ship
                        ; type's blueprint and stores it in XX0

 LDA XX21-1,Y           ; Fetch the high byte of this particular ship type's
 STA XX0+1              ; blueprint and store it in XX0+1