Start and end: BR1 (Part 2 of 2)

       Name: BR1 (Part 2 of 2)                                       [Show more]
       Type: Subroutine
   Category: Start and end
    Summary: Show the "Press Fire or Space, Commander" screen and start the
             game
    Context: See this subroutine in context in the source code
 References: No direct references to this subroutine in this source file


 BRKV is set to point to BR1 by the loading process.


 JSR msblob             ; Reset the dashboard's missile indicators so none of
                        ; them are targeted

 LDA #7                 ; Call TITLE to show a rotating Adder (#ADA) and token
 LDX #ADA               ; 7 ("PRESS SPACE OR FIRE,{single cap}COMMANDER.{cr}
 LDY #48                ; {cr}"), with the ship at a distance of 48, returning
 JSR TITLE              ; with the internal number of the key pressed in A

IF _GMA_RELEASE

 JSR stopat             ; Stop playing the title music

ENDIF

 JSR ping               ; Set the target system coordinates (QQ9, QQ10) to the
                        ; current system coordinates (QQ0, QQ1) we just loaded

 JSR TT111              ; Select the system closest to galactic coordinates
                        ; (QQ9, QQ10)

 JSR jmp                ; Set the current system to the selected system

 LDX #5                 ; We now want to copy the seeds for the selected system
                        ; in QQ15 into QQ2, where we store the seeds for the
                        ; current system, so set up a counter in X for copying
                        ; 6 bytes (for three 16-bit seeds)

                        ; The label below is called likeTT112 because this code
                        ; is almost identical to the TT112 loop in the hyp1
                        ; routine

.likeTT112

 LDA QQ15,X             ; Copy the X-th byte in QQ15 to the X-th byte in QQ2
 STA QQ2,X

 DEX                    ; Decrement the counter

 BPL likeTT112          ; Loop back to likeTT112 if we still have more bytes to
                        ; copy

 INX                    ; Set X = 0 (as we ended the above loop with X = $FF)

 STX EV                 ; Set EV, the extra vessels spawning counter, to 0, as
                        ; we are entering a new system with no extra vessels
                        ; spawned

 LDA QQ3                ; Set the current system's economy in QQ28 to the
 STA QQ28               ; selected system's economy from QQ3

 LDA QQ5                ; Set the current system's tech level in tek to the
 STA tek                ; selected system's economy from QQ5

 LDA QQ4                ; Set the current system's government in gov to the
 STA gov                ; selected system's government from QQ4

                        ; Fall through into the docking bay routine below