Start and end: BR1 (Part 1 of 2)

       Name: BR1 (Part 1 of 2)                                       [Show more]
       Type: Subroutine
   Category: Start and end
    Summary: Show the "Load New Commander (Y/N)?" screen and start the game
    Context: See this subroutine in context in the source code
 References: This subroutine is called as follows:
             * BRBR calls BR1
             * TT102 calls via QU5


 Other entry points:

   QU5                  Restart the game using the last saved commander without
                        asking whether to load a new commander file


.BR1

 JSR ZEKTRAN            ; Call ZEKTRAN to clear the key logger

 LDA #3                 ; Move the text cursor to column 3
 JSR DOXC

IF _GMA_RELEASE

 JSR startat            ; Start playing the title music

ELIF _SOURCE_DISK

;JSR FX200              ; This instruction is commented out in the original
                        ; source

ENDIF

 LDX #CYL               ; Call TITLE to show a rotating Cobra Mk III (#CYL) and
 LDA #6                 ; token 6 ("LOAD NEW {single cap}COMMANDER {all caps}
 LDY #210               ; (Y/N)?{sentence case}{cr}{cr}"), with the ship at a
 JSR TITLE              ; distance of 210, returning with the internal number
                        ; of the key pressed in A

 CMP #YINT              ; Did we press "Y"? If not, jump to QU5, otherwise
 BNE QU5                ; continue on to load a new commander

IF _GMA_RELEASE

 JSR stopat             ; Stop playing the title music

ENDIF

 JSR DFAULT             ; Call DFAULT to reset the current commander data block
                        ; to the last saved commander

 JSR SVE                ; Call SVE to load a new commander into the last saved
                        ; commander data block

IF _GMA_RELEASE

 JSR startat            ; Start playing the title music

ENDIF

.QU5

 JSR DFAULT             ; Call DFAULT to reset the current commander data block
                        ; to the last saved commander