Text: MT17

       Name: MT17                                                    [Show more]
       Type: Subroutine
   Category: Text
    Summary: Print the selected system's adjective, e.g. Lavian for Lave
  Deep dive: Extended text tokens
    Context: See this subroutine in context in the source code
 References: This subroutine is called as follows:
             * JMTB calls MT17


 The adjective for the current system is generated by taking the system name,
 removing the last character if it is a vowel, and adding "-ian" to the end,
 so:

   * Lave gives Lavian (as in "Lavian tree grub")

   * Leesti gives Leestian (as in "Leestian Evil Juice")

 This routine is called by jump token 17, {system name adjective}, and it can
 only be used when justified text is being printed - i.e. following jump token
 14, {justify} - because the routine needs to use the line buffer to work.


.MT17

 LDA QQ17               ; Set QQ17 = %10111111 to switch to Sentence Case
 AND #%10111111
 STA QQ17

 LDA #3                 ; Print control code 3 (selected system name) into the
 JSR TT27               ; line buffer

 LDX DTW5               ; Load the last character of the line buffer BUF into A
 LDA BUF-1,X            ; (as DTW5 contains the buffer size, so character DTW5-1
                        ; is the last character in the buffer BUF)

 JSR VOWEL              ; Test whether the character is a vowel, in which case
                        ; this will set the C flag

 BCC MT171              ; If the character is not a vowel, skip the following
                        ; instruction

 DEC DTW5               ; The character is a vowel, so decrement DTW5, which
                        ; removes the last character from the line buffer (i.e.
                        ; it removes the trailing vowel from the system name)

.MT171

 LDA #153               ; Print extended token 153 ("IAN"), returning from the
 JMP DETOK              ; subroutine using a tail call