Maths (Arithmetic): LL129

       Name: LL129                                                   [Show more]
       Type: Subroutine
   Category: Maths (Arithmetic)
    Summary: Calculate Q = XX12+2, A = S EOR XX12+3 and (S R) = |S R|
    Context: See this subroutine in context in the source code
 References: This subroutine is called as follows:
             * LL120 calls LL129
             * LL123 calls LL129


 Do the following, in this order:

   Q = XX12+2

   A = S EOR XX12+3

   (S R) = |S R|

 This sets up the variables required above to calculate (S R) / XX12+2 and give
 the result the opposite sign to XX13+3.


.LL129

 LDX XX12+2             ; Set Q = XX12+2
 STX Q

 LDA S                  ; If S is positive, jump to LL127
 BPL LL127

 LDA #0                 ; Otherwise set R = -R
 SEC
 SBC R
 STA R

 LDA S                  ; Push S onto the stack
 PHA

 EOR #%11111111         ; Set S = ~S + 1 + C
 ADC #0
 STA S

 PLA                    ; Pull the original, negative S from the stack into A

.LL127

 EOR XX12+3             ; Set A = original argument S EOR'd with XX12+3

 RTS                    ; Return from the subroutine